src/diagnostics/kcounter/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")
import("//src/sys/core/build/core_shard.gni")

rustc_library("lib") {
  name = "kcounter"
  edition = "2021"
  with_unit_tests = true

  visibility = [
    "//src/diagnostics/kcounter/*",
    "//src/diagnostics/launcher/*",
  ]

  deps = [
    "//sdk/fidl/fuchsia.kernel:fuchsia.kernel_rust",
    "//sdk/fidl/fuchsia.mem:fuchsia.mem_rust",
    "//src/lib/diagnostics/inspect/runtime/rust",
    "//src/lib/diagnostics/inspect/rust",
    "//src/lib/fuchsia-component",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:argh",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  test_deps = [
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
  ]

  sources = [ "src/lib.rs" ]
}

fuchsia_package_with_single_component("diagnostics-kcounter") {
  manifest = "meta/diagnostics-kcounter.cml"
  deps = [ "//src/diagnostics/launcher:bin" ]
}

fuchsia_unittest_package("diagnostics-kcounter-tests") {
  deps = [ ":lib_test" ]
}

core_shard("core_shard") {
  shard_file = "meta/diagnostics-kcounter.core_shard.cml"
}

group("tests") {
  testonly = true
  deps = [ ":diagnostics-kcounter-tests" ]
}

group("kcounter") {
  testonly = true
  deps = [ ":diagnostics-kcounter" ]
}