sdk/lib/ld/testing/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/cpp/library_headers.gni")

group("testing") {
  testonly = true
  public_deps = [ ":ld-testing" ]
}

library_headers("headers") {
  testonly = true

  headers = []
  public_deps = []
  if (is_fuchsia) {
    headers += [
      "lib/ld/testing/mock-loader-service.h",
      "lib/ld/testing/test-processargs.h",
    ]
    public_deps += [
      "//sdk/fidl/fuchsia.ldsvc:fuchsia.ldsvc_cpp",
      "//third_party/googletest:gmock",
      "//zircon/system/ulib/async-loop:async-loop-cpp",
      "//zircon/system/ulib/async-loop:async-loop-default",
      "//zircon/system/ulib/fbl",
      "//zircon/system/ulib/zx",
    ]
  }
}

static_library("ld-testing") {
  testonly = true

  public_deps = [ ":headers" ]

  sources = []
  deps = []
  if (is_fuchsia) {
    sources += [
      "mock-loader-service.cc",
      "test-processargs.cc",
    ]
    deps += [
      "//sdk/lib/fdio",
      "//sdk/lib/stdcompat",
      "//src/lib/elfldltl/testing",
      "//third_party/googletest:gtest",
      "//zircon/system/ulib/zx",
    ]
  }
}