src/lib/debug/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [
    ":backtrace-request-integration-test-pkg",
    ":backtrace-request-test-pkg",
  ]

  if (current_cpu == "riscv64") {
    deps -= [
      # TODO(fxbug.dev/129959): Fix the build and remove from this list.
      ":backtrace-request-test-pkg",
    ]
  }
}

test("backtrace-request-test") {
  sources = [ "backtrace-request-test.cc" ]
  deps = [
    "//sdk/lib/fdio",
    "//src/lib/debug:backtrace-request",
    "//src/lib/debug:backtrace-request-utils",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("backtrace-request-test-pkg") {
  package_name = "backtrace-request-test"
  deps = [ ":backtrace-request-test" ]
}

# Integration test for requesting a backtrace.
#
# Related unittests exist alongside the backtrace and crashsvc code, but
# this verifies that the pieces are working together correctly.
test("backtrace-request-integration-test") {
  sources = [ "backtrace-request-integration-test.cc" ]
  deps = [
    "//sdk/lib/fdio",
    "//src/lib/debug:backtrace-request",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("backtrace-request-integration-test-pkg") {
  package_name = "backtrace-request-integration-test"
  deps = [ ":backtrace-request-integration-test" ]
}