zircon/system/utest/int-types/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

##########################################
# Though under //zircon, this build file #
# is meant to be used in the Fuchsia GN  #
# build.                                 #
# See fxb/36139.                         #
##########################################

assert(!defined(zx) || zx != "/",
       "This file can only be used in the Fuchsia GN build.")

import("//build/test.gni")
import("//build/test/test_package.gni")

test("int-types") {
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [
    "int-types.c",
    "int-types.cc",
    "wchar-type.c",
    "wchar-type.cc",
  ]
  configs += [ ":config" ]
  deps = [
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/zxtest",
  ]
}

config("config") {
  visibility = [ ":*" ]

  # The C file here uses a macro to detect whether a type is signed, by
  # comparing the values of -1 and 0. This leads to complaints about
  # vacuously true comparisons, which we don't care about.
  cflags = [ "-Wno-type-limits" ]
}

unittest_package("int-types-package") {
  package_name = "int-types"
  deps = [ ":int-types" ]

  tests = [
    {
      name = "int-types"
      dest = "int-types-test"
    },
  ]
}