src/ui/tests/e2e_input_tests/scenic/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test.gni")
import("//build/test/test_package.gni")

group("tests") {
  testonly = true

  deps = [ ":e2e_input_tests" ]
}

test_package("e2e_input_tests") {
  deps = [
    ":mediabuttons_listener_test",
    ":minimal_input_test",
  ]

  tests = [
    {
      name = "minimal_input_test"
      environments = [
        {
          dimensions = nuc_env.dimensions
          tags = [ "flaky" ]  # Bug 49361
        },
      ]
    },
    {
      name = "mediabuttons_listener_test"
      environments = [ nuc_env ]
    },
  ]
}

# Each e2e test must run in its own executable.
test("minimal_input_test") {
  sources = [ "minimal_input_test.cc" ]
  output_name = "minimal_input_test"
  deps = [
    "//garnet/public/lib/fostr/fidl/fuchsia.ui.input",
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.ui.input",
    "//sdk/fidl/fuchsia.ui.policy",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/ui/base_view",
    "//third_party/googletest:gtest",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/fit",
    "//zircon/public/lib/zx",
  ]
}

# Each e2e test must run in its own executable.
test("mediabuttons_listener_test") {
  sources = [ "mediabuttons_listener_test.cc" ]
  output_name = "mediabuttons_listener_test"
  deps = [
    "//garnet/public/lib/fostr/fidl/fuchsia.ui.input",
    "//garnet/public/lib/gtest",
    "//sdk/fidl/fuchsia.ui.input",
    "//sdk/fidl/fuchsia.ui.policy",
    "//sdk/fidl/fuchsia.ui.scenic",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fxl",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/ui/base_view",
    "//third_party/googletest:gtest",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/fit",
    "//zircon/public/lib/zx",
  ]
}