src/developer/shell/josh/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")

test("josh_tests_bin") {
  deps = [
    "//sdk/lib/fidl/cpp/test",
    "//src/developer/shell/josh/console:tests",
    "//src/developer/shell/josh/lib:tests",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gtest",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/async-loop-default",
  ]

  # Extra stack needed to avoid crashes when calling QuickJS functions
  # with asan enabled.
  ldflags = [ "-Wl,-z,stack-size=0x200000" ]

  # TODO(47462): Fix the leaks and remove this.
  deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

executable("bin") {
  output_name = "josh"

  sources = [ "main.cc" ]

  deps = [
    "//src/developer/shell/josh/console",
    "//src/developer/shell/josh/lib",
  ]

  libs = [ "zircon" ]

  # Extra stack needed to avoid crashes when calling QuickJS functions
  # with asan enabled.
  ldflags = [ "-Wl,-z,stack-size=0x200000" ]

  # TODO(46840): Fix the leaks and remove this.
  deps += [
    "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS",
    "//src/lib/syslog/cpp",
  ]
}