src/connectivity/wlan/drivers/testing/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/drivers.gni")

group("testing") {
  testonly = true
  public_deps = [ ":wlanphy-testdev" ]
}

driver_bind_rules("wlanphy_test_bind") {
  disable_autobind = true
  rules = "wlanphy_test.bind"
  header_output = "wlanphy_test_bind.h"
  tests = "bind_tests.json"
  deps = [ "//src/devices/bind/fuchsia.test" ]
}

group("tests") {
  testonly = true
  deps = [ ":wlanphy_test_bind_test" ]
}

fuchsia_driver("wlanphy-testdev-driver") {
  output_name = "wlanphy-testdev"
  sources = [
    "driver.cc",
    "iface-device.cc",
    "iface-device.h",
    "phy-device.cc",
    "phy-device.h",
  ]

  deps = [
    ":wlanphy_test_bind",
    "//sdk/banjo/fuchsia.hardware.sdio:fuchsia.hardware.sdio_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.test:fuchsia.hardware.test_banjo_cpp",
    "//sdk/fidl/fuchsia.wlan.common:fuchsia.wlan.common_banjo_c",
    "//sdk/fidl/fuchsia.wlan.device:fuchsia.wlan.device_llcpp",
    "//sdk/fidl/fuchsia.wlan.internal:fuchsia.wlan.internal_banjo_c",
    "//src/connectivity/wlan/lib/common/cpp:common",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
    "//zircon/system/ulib/async:async-cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/zx",
  ]

  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]

  # TODO(https://fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

fuchsia_driver_component("wlanphy-testdev") {
  component_name = "wlanphy-testdev"
  deps = [ ":wlanphy-testdev-driver" ]
  info = "wlanphy-testdev-info.json"
  colocate = true
}