src/lib/diagnostics/testing/rust/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_library.gni")

group("rust") {
  deps = [ ":lib" ]
}

group("tests") {
  testonly = true
  deps = [ ":diagnostics-testing-tests" ]
}

rustc_library("lib") {
  visibility = [
    "//src/diagnostics/iquery/*",
    "//src/lib/diagnostics/testing/*",
  ]
  name = "diagnostics_testing"
  with_unit_tests = true

  deps = [
    "//sdk/fidl/fuchsia.diagnostics:fuchsia.diagnostics-rustc",
    "//sdk/fidl/fuchsia.logger:fuchsia.logger-rustc",
    "//sdk/fidl/fuchsia.sys:fuchsia.sys-rustc",
    "//src/lib/diagnostics/data/rust",
    "//src/lib/diagnostics/hierarchy/rust",
    "//src/lib/diagnostics/reader/rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-url",
    "//src/lib/syslog/rust:syslog-listener",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  sources = [ "src/lib.rs" ]
}

fuchsia_unittest_package("diagnostics-testing-tests") {
  manifest = "meta/diagnostics-testing-unittest.cmx"
  deps = [
    ":emitter-for-test",
    ":lib_test",
  ]
}

fuchsia_component("emitter-for-test") {
  testonly = true
  deps = [
    ":emitter-bin",
    "//src/lib/diagnostics/inspect/runtime/rust:inspect_test_component_v1",
  ]
  manifest = "meta/emitter-for-test.cmx"
}

rustc_binary("emitter-bin") {
  output_name = "emitter_bin"
  testonly = true
  edition = "2018"
  source_root = "test/emitter.rs"

  deps = [
    "//sdk/fidl/fuchsia.sys:fuchsia.sys-rustc",
    "//src/lib/diagnostics/inspect/runtime/rust",
    "//src/lib/diagnostics/inspect/rust",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/syslog/rust:syslog",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
  ]

  sources = [ "test/emitter.rs" ]
}