zircon/system/ulib/gpt/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test.gni")
import("//build/testing/bootfs_test.gni")

group("test") {
  testonly = true
  deps = [ ":gpt-unit" ]
}

test("gpt-unit") {
  output_name = "gpt-unit-test"
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [
    "gpt-tests.cc",
    "main.cc",
  ]
  include_dirs = [
    "//zircon/system/ulib/gpt",
    "..",
  ]
  deps = [
    "//sdk/fidl/fuchsia.hardware.block:fuchsia.hardware.block_c",
    "//sdk/lib/fdio",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
    "//zircon/system/ulib/fdio-caller",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/gpt",
    "//zircon/system/ulib/mbr",
    "//zircon/system/ulib/ramdevice-client",
    "//zircon/third_party/ulib/cksum",
  ]
}

bootfs_test("gpt-unit-bootfs-test") {
  name = "gpt-unit-test"
  deps = [ ":gpt-unit" ]
}