src/media/audio/lib/timeline/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test/test_package.gni")

source_set("timeline") {
  sources = [
    "timeline_function.cc",
    "timeline_function.h",
    "timeline_rate.cc",
    "timeline_rate.h",
  ]

  deps = [ "//sdk/lib/syslog/cpp" ]

  public_deps = [ "//zircon/public/lib/zx" ]

  # TODO(fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

executable("unittest_bin") {
  visibility = [ ":*" ]
  testonly = true
  output_name = "audio-libtimeline-unittests"

  sources = [
    "timeline_function_unittest.cc",
    "timeline_rate_unittest.cc",
  ]

  deps = [
    ":timeline",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
  ]
}

test_package("audio-libtimeline-unittests") {
  deps = [ ":unittest_bin" ]

  tests = [
    {
      name = "audio-libtimeline-unittests"

      # This test does not require, nor behave differently on, a non-virtualized target
      environments = basic_envs
    },
  ]
}

group("tests") {
  testonly = true
  deps = [ ":audio-libtimeline-unittests" ]
}