src/lib/fuchsia-component/component-launching-test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")
import("//build/test/test_package.gni")

rustc_test("driver") {
  name = "component_launching_test"
  edition = "2018"

  deps = [
    "//src/lib/fdio/rust:fdio",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/testing/fidl:placeholders-rustc",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tempfile",
  ]

  sources = [ "src/lib.rs" ]
}

rustc_binary("echo_service_checker_bin") {
  name = "echo_service_checker"
  edition = "2018"
  source_root = "src/echo_service_checker.rs"
  testonly = true

  deps = [
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/testing/fidl:placeholders-rustc",
    "//third_party/rust_crates:anyhow",
  ]

  sources = [ "src/echo_service_checker.rs" ]
}

rustc_binary("echo_service_checker_with_probe_bin") {
  name = "echo_service_checker_with_probe"
  edition = "2018"
  source_root = "src/echo_service_checker_with_probe.rs"
  testonly = true

  deps = [
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/testing/fidl:placeholders-rustc",
    "//third_party/rust_crates:anyhow",
  ]

  sources = [ "src/echo_service_checker_with_probe.rs" ]
}

rustc_binary("injected_directory_checker_bin") {
  name = "injected_directory_checker"
  edition = "2018"
  source_root = "src/injected_directory_checker.rs"
  testonly = true

  sources = [ "src/injected_directory_checker.rs" ]
}

rustc_binary("stdio_writer_bin") {
  name = "stdio_writer"
  edition = "2018"
  source_root = "src/stdio_writer.rs"
  testonly = true

  sources = [ "src/stdio_writer.rs" ]
}

test_package("component-launching-tests") {
  deps = [
    ":driver",
    ":echo_service_checker_bin",
    ":echo_service_checker_with_probe_bin",
    ":injected_directory_checker_bin",
    ":stdio_writer_bin",
  ]

  binaries = [
    {
      name = "echo_service_checker"
      dest = "echo-service-checker"
    },
    {
      name = "echo_service_checker_with_probe"
      dest = "echo-service-checker-with-probe"
    },
    {
      name = "injected_directory_checker"
      dest = "injected-directory-checker"
    },
    {
      name = "stdio_writer"
      dest = "stdio-writer"
    },
  ]

  meta = [
    {
      path = rebase_path("meta/echo-service-checker.cmx")
      dest = "echo-service-checker.cmx"
    },
    {
      path = rebase_path("meta/echo-service-checker-with-probe.cmx")
      dest = "echo-service-checker-with-probe.cmx"
    },
    {
      path = rebase_path("meta/injected-directory-checker.cmx")
      dest = "injected-directory-checker.cmx"
    },
    {
      path = rebase_path("meta/stdio-writer.cmx")
      dest = "stdio-writer.cmx"
    },
  ]

  tests = [
    {
      name = "component_launching_test"
      dest = "component-launching-test"
    },
  ]
}