src/connectivity/wlan/drivers/wlan/BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/fuchsia/rules.gni")
import("//build/driver_package.gni")
import("//build/test/test_package.gni")

config("wlan_config") {
  include_dirs = [ "." ]
}

driver_module("wlan_driver") {
  output_name = "wlan"
  sources = [
    "device.cc",
    "device.h",
    "driver.cc",
    "minstrel.cc",
    "minstrel.h",
    "probe_sequence.cc",
    "probe_sequence.h",
  ]

  deps = [
    "//sdk/banjo/ddk.hw.wlan.wlaninfo",
    "//sdk/banjo/fuchsia.hardware.ethernet",
    "//src/connectivity/wlan/lib/mlme/cpp:mlme",
    "//src/devices/lib/dev-operation",
    "//src/devices/lib/driver",
    "//src/lib/ddk",

    # TODO(fxb/38132): Migrate to the new bind rules and delete the below
    "//src/lib/ddk:ddk-deprecated-binding-headers",
    "//src/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zx",
  ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
}

executable("wlan_minstrel_unittest") {
  testonly = true
  sources = [
    "minstrel.cc",
    "minstrel.h",
    "probe_sequence.cc",
    "probe_sequence.h",
    "tests/minstrel_unittest.cc",
    "tests/probe_sequence_unittest.cc",
  ]

  deps = [
    "//garnet/lib/wlan/protocol",
    "//src/connectivity/wlan/lib/common/cpp:common",
    "//src/connectivity/wlan/lib/mlme/cpp:mlme",
    "//src/connectivity/wlan/lib/mlme/cpp/tests:test_main",
    "//src/lib/timekeeper:testing",
    "//third_party/googletest:gtest",
    "//zircon/public/lib/fbl",
  ]

  configs +=
      [ "//src/connectivity/wlan/lib/mlme/cpp/tests:wlan_mlme_tests_config" ]
}

test_package("wlan_drivers_tests") {
  deps = [ ":wlan_minstrel_unittest" ]
  tests = [
    {
      name = "wlan_minstrel_unittest"
    },
  ]
}

driver_package("wlan") {
  package_name = "wlan-system"

  deps = [ ":wlan_driver" ]

  drivers = [
    {
      name = "wlan.so"
    },
  ]
}