examples/components/routing/integration_tests/rust/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_test.gni")

# [START example_snippet]
rustc_test("bin") {
  name = "echo_integration_test_rust"
  edition = "2021"

  deps = [
    "//examples/components/routing/fidl:echo-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//third_party/rust_crates:anyhow",
  ]

  sources = [ "src/lib.rs" ]
}

fuchsia_component("echo_integration_test_component") {
  testonly = true
  component_name = "echo_integration_test"
  manifest = "meta/echo_integration_test.cml"
  deps = [ ":bin" ]
}

fuchsia_test_package("echo_integration_test_rust") {
  test_components = [ ":echo_integration_test_component" ]
  deps =
      [ "//examples/components/routing/rust/echo_server:echo_server_component" ]
}

# [END example_snippet]

fuchsia_component("subpackaged_echo_integration_test_component") {
  testonly = true
  component_name = "echo_integration_test"
  manifest = "meta/subpackaged_echo_integration_test.cml"
  deps = [ ":bin" ]
}

fuchsia_test_package("subpackaged_echo_integration_test_rust") {
  test_components = [ ":subpackaged_echo_integration_test_component" ]
  subpackages = [
    {
      package =
          "//examples/components/routing/rust/echo_server:echo_server_package"
    },
  ]
}