src/lib/fuchsia-component/tests/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/fidl/fidl.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

rustc_test("fuchsia-component-v1-test") {
  edition = "2018"
  source_root = "components_v1/lib.rs"
  deps = [
    ":fuchsia.component.test-rustc",
    "//garnet/lib/rust/files_async",
    "//garnet/lib/rust/io_util",
    "//sdk/fidl/fuchsia.io:fuchsia.io-rustc",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/storage/pseudo-fs",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:matches",
    "//third_party/rust_crates:thiserror",
  ]

  sources = [ "components_v1/lib.rs" ]
}

fidl("fuchsia.component.test") {
  sources = [ "test.test.fidl" ]
}

fidl("fuchsia.component.client.test") {
  sources = [ "client.test.fidl" ]
}

fuchsia_component("fuchsia_component_v1_test_component") {
  component_name = "fuchsia_component_v1_test"
  manifest = "meta/fuchsia_component_v1_test.cmx"
  testonly = true
  deps = [ ":fuchsia-component-v1-test" ]
}

fuchsia_test_package("fuchsia-component-tests") {
  test_components = [ ":fuchsia_component_v1_test_component" ]
  deps = [ "//examples/components/routing/echo_server:echo_server_component" ]
}

group("tests") {
  testonly = true
  deps = [ ":fuchsia-component-tests" ]
}