src/devices/spi/drivers/mtk-spi/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [
    ":mtk-spi-test",
    ":mtk_spi_bind_test",
  ]
}

bind_rules("mtk_spi_bind") {
  rules = "mtk_spi.bind"
  output = "mtk_spi_bind.h"
  tests = "bind_tests.json"
  deps = [
    "//src/devices/bind/fuchsia.mediatek.platform",
    "//src/devices/bind/fuchsia.platform",
  ]
}

driver_module("mtk-spi") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  sources = [ "mtk-spi.cc" ]
  deps = [
    ":mtk_spi_bind",
    "//sdk/banjo/fuchsia.hardware.spiimpl",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/bus/lib/device-protocol-platform-device",
    "//src/devices/lib/driver",
    "//src/devices/lib/mmio",
    "//src/lib/ddk",
    "//src/lib/ddk:ddk-metadata-headers",
    "//src/lib/ddktl",
    "//zircon/public/lib/hwreg",
    "//zircon/public/lib/sync",
  ]
}

test("mtk-spi-test-bin") {
  configs += [ "//build/unification/config:zircon-migrated" ]
  output_name = "mtk-spi-test"
  sources = [
    "mtk-spi-test.cc",
    "mtk-spi.cc",
  ]
  deps = [
    ":mtk_spi_bind",
    "//sdk/banjo/fuchsia.hardware.spiimpl",
    "//src/devices/bus/lib/device-protocol-pdev",
    "//src/devices/bus/lib/device-protocol-platform-device",
    "//src/devices/lib/driver",
    "//src/devices/lib/mmio",
    "//src/devices/testing/fake_ddk",
    "//src/devices/testing/mock-mmio-reg",
    "//src/lib/ddk",
    "//src/lib/ddk:ddk-metadata-headers",
    "//src/lib/ddktl",
    "//zircon/public/lib/hwreg",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
  ]
}

fuchsia_unittest_package("mtk-spi-test") {
  deps = [ ":mtk-spi-test-bin" ]
}