src/sys/appmgr/integration_tests/lifecycle/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/testing/environments.gni")
import("//src/sys/build/components.gni")

group("lifecycle") {
  testonly = true
  deps = [ ":appmgr-lifecycle-tests" ]
}

executable("appmgr-lifecycle-tests-bin") {
  testonly = true
  output_name = "appmgr-lifecycle-tests"

  sources = [ "appmgr_lifecycle_tests.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.process.lifecycle:fuchsia.process.lifecycle",
    "//sdk/lib/sys/cpp/testing:integration",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/sys/appmgr:appmgr_for_test",
    "//src/sys/appmgr:lib",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("test-lifecycle-component-bin") {
  testonly = true

  output_name = "test-lifecycle-component"

  sources = [ "test_lifecycle_component.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.process.lifecycle:fuchsia.process.lifecycle",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("test-sysmgr-bin") {
  testonly = true

  output_name = "test-sysmgr"

  sources = [ "test_sysmgr.cc" ]

  deps = [
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

fuchsia_component("test-lifecycle-component") {
  testonly = true
  deps = [ ":test-lifecycle-component-bin" ]
  manifest = "meta/test-lifecycle-component.cmx"
}

fuchsia_component("test-sysmgr") {
  testonly = true
  deps = [ ":test-sysmgr-bin" ]
  manifest = "meta/test-sysmgr.cmx"
}

fuchsia_unittest_package("appmgr-lifecycle-tests") {
  manifest = "meta/appmgr-lifecycle-tests.cmx"
  deps = [
    ":appmgr-lifecycle-tests-bin",
    ":test-lifecycle-component",
    ":test-sysmgr",
  ]
  test_specs = {
    environments = basic_envs
  }
}