src/connectivity/bluetooth/core/bt-gap/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/rust/rustc_binary.gni")
import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

rustc_binary("bin") {
  name = "bt_gap"
  edition = "2018"
  with_unit_tests = true

  deps = [
    "//garnet/lib/rust/io_util",
    "//sdk/fidl/fuchsia.bluetooth:fuchsia.bluetooth-rustc",
    "//sdk/fidl/fuchsia.bluetooth.bredr:fuchsia.bluetooth.bredr-rustc",
    "//sdk/fidl/fuchsia.bluetooth.control:fuchsia.bluetooth.control-rustc",
    "//sdk/fidl/fuchsia.bluetooth.gatt:fuchsia.bluetooth.gatt-rustc",
    "//sdk/fidl/fuchsia.bluetooth.le:fuchsia.bluetooth.le-rustc",
    "//sdk/fidl/fuchsia.bluetooth.sys:fuchsia.bluetooth.sys-rustc",
    "//sdk/fidl/fuchsia.cobalt:fuchsia.cobalt-rustc",
    "//sdk/fidl/fuchsia.device:fuchsia.device-rustc",
    "//sdk/fidl/fuchsia.logger:fuchsia.logger-rustc",
    "//sdk/fidl/fuchsia.mem:fuchsia.mem-rustc",
    "//sdk/fidl/fuchsia.stash:fuchsia.stash-rustc",
    "//sdk/fidl/fuchsia.sys:fuchsia.sys-rustc",
    "//src/connectivity/bluetooth/fidl:host-rustc",
    "//src/connectivity/bluetooth/lib/async-helpers",
    "//src/connectivity/bluetooth/lib/fuchsia-bluetooth",
    "//src/lib/async-utils",
    "//src/lib/diagnostics/inspect/rust",
    "//src/lib/fdio/rust:fdio",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/storage/fuchsia-vfs-watcher",
    "//src/lib/syslog/rust:syslog",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:futures-test",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:matches",
    "//third_party/rust_crates:parking_lot",
    "//third_party/rust_crates:pin-utils",
    "//third_party/rust_crates:proptest",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:serde_json",
    "//third_party/rust_crates:slab",
    "//third_party/rust_crates:tempfile",
    "//third_party/rust_crates:thiserror",
  ]

  sources = [
    "src/adapters.rs",
    "src/build_config.rs",
    "src/generic_access_service.rs",
    "src/host_device.rs",
    "src/host_dispatcher.rs",
    "src/main.rs",
    "src/services/access.rs",
    "src/services/bootstrap.rs",
    "src/services/configuration.rs",
    "src/services/control.rs",
    "src/services/host_watcher.rs",
    "src/services/mod.rs",
    "src/services/pairing/mod.rs",
    "src/services/pairing/pairing_dispatcher.rs",
    "src/services/pairing/pairing_requests.rs",
    "src/store/in_memory.rs",
    "src/store/keys.rs",
    "src/store/mod.rs",
    "src/store/serde.rs",
    "src/store/stash.rs",
    "src/test/access.rs",
    "src/test/configuration.rs",
    "src/test/control.rs",
    "src/test/discovery.rs",
    "src/test/host_device.rs",
    "src/test/mod.rs",
    "src/types.rs",
    "src/watch_peers.rs",
  ]
}

package("bt-gap") {
  deps = [ ":bin" ]

  binaries = [
    {
      name = "bt_gap"
    },
  ]
  meta = [
    {
      path = rebase_path("meta/bt-gap.cmx")
      dest = "bt-gap.cmx"
    },
  ]
  resources = [
    {
      path = rebase_path("config/default.json")
      dest = "default.json"
    },
  ]
}

test_package("tests") {
  package_name = "bt-gap-tests"

  deps = [ ":bin_test" ]

  tests = [
    {
      name = "bt_gap_bin_test"
      dest = "bt-gap-unittests"
      environments = basic_envs
    },
  ]

  resources = [
    {
      path = rebase_path("config/default.json")
      dest = "default.json"
    },
  ]
}