zircon/system/ulib/trace-reader/test/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test.gni")
import("//build/testing/bootfs_test.gni")

group("tests") {
  testonly = true
  deps = [ ":trace-reader-test($host_toolchain)" ]
}

test("trace-reader-test") {
  output_name = "trace-reader-test-test"
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [
    "file_reader_tests.cc",
    "reader_tests.cc",
    "records_tests.cc",
  ]
  deps = [
    "//sdk/lib/fit",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/trace-engine:trace-engine-headers-for-reader",
    "//zircon/system/ulib/trace-reader",
    "//zircon/system/ulib/zxtest",
  ]
  if (is_fuchsia) {
    deps += [
      "//sdk/lib/fdio",
      "//zircon/system/ulib/zx",
    ]
  }
}

bootfs_test("trace-reader-test-bootfs-test") {
  name = "trace-reader-test-test"
  deps = [ ":trace-reader-test" ]
}