zircon/system/ulib/elf-search/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")
import("//build/testing/bootfs_test.gni")

group("test") {
  testonly = true
  deps = [ ":elf-search-test-pkg" ]
}

executable("elf-search-test-helper") {
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [ "helper.cc" ]
  visibility = [ ":*" ]
}

test("elf-search") {
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  sources = [ "elf-search-test.cc" ]
  deps = [
    "//sdk/lib/fdio",
    "//src/lib/elfldltl",
    "//zircon/system/ulib/elf-search",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/test-utils",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
  ]
  data_deps = [ ":elf-search-test-helper" ]
  include_dirs = [ "include" ]
}

bootfs_test("elf-search-bootfs-test") {
  name = "elf-search"
  deps = [ ":elf-search" ]
}

fuchsia_unittest_package("elf-search-test-pkg") {
  package_name = "elf-search-test"
  manifest = "meta/elf-search-test.cml"
  deps = [ ":elf-search" ]
}