src/ui/input/drivers/hid/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("hid_bind") {
  rules = "hid.bind"
  bind_output = "hid.bindbc"
  tests = "tests.json"
  deps = [ "//src/devices/bind/fuchsia.hid" ]
}

fuchsia_driver("hid-driver") {
  output_name = "hid"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [
    "device-report-reader.cc",
    "hid-fifo.c",
    "hid-instance.cc",
    "hid.cc",
  ]
  deps = [
    ":hid_bind",
    "//sdk/banjo/fuchsia.hardware.hiddevice:fuchsia.hardware.hiddevice_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.hidbus:fuchsia.hardware.hidbus_cpp",
    "//sdk/fidl/fuchsia.hardware.input:fuchsia.hardware.input_cpp",
    "//src/devices/bind/fuchsia.hid:fuchsia.hid_cpp",
    "//src/devices/lib/driver",
    "//src/devices/lib/driver:driver_runtime",
    "//src/lib/ddk",
    "//src/lib/listnode",
    "//src/ui/input/lib/hid",
    "//src/ui/input/lib/hid-parser",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/trace",
  ]

  # TODO(https://fxbug.dev/42085293): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-vla-cxx-extension" ]
}

fuchsia_driver_component("hid") {
  visibility = [ ":*" ]
  component_name = "hid"
  deps = [ ":hid-driver" ]
  info = "hid-info.json"
  manifest = "meta/hid.cml"
}

fuchsia_driver_package("package") {
  package_name = "hid"
  driver_components = [ ":hid" ]
}

test("hid-test") {
  sources = [
    "device-report-reader.cc",
    "hid-fifo.c",
    "hid-instance.cc",
    "hid-test.cc",
    "hid.cc",
  ]
  deps = [
    ":hid_bind",
    "//sdk/banjo/fuchsia.hardware.hiddevice:fuchsia.hardware.hiddevice_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.hidbus:fuchsia.hardware.hidbus_cpp",
    "//sdk/fidl/fuchsia.hardware.hidbus:fuchsia.hardware.hidbus_cpp_testing",
    "//sdk/fidl/fuchsia.hardware.input:fuchsia.hardware.input_cpp",
    "//sdk/lib/driver/runtime/testing/cpp",
    "//sdk/lib/driver/testing/cpp",
    "//src/devices/bind/fuchsia.hid:fuchsia.hid_cpp",
    "//src/devices/lib/driver:driver_runtime",
    "//src/devices/testing/mock-ddk",
    "//src/lib/ddk",
    "//src/lib/listnode",
    "//src/ui/input/lib/hid",
    "//src/ui/input/lib/hid-parser",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/trace",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("hid-test-package") {
  package_name = "hid-test"
  deps = [ ":hid-test" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [
    ":hid-test-package",
    ":hid_bind_test",
  ]
}