src/ui/examples/escher/BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/dist/renamed_binary.gni")

# NOTE: whenever a new example is added, also add it to
# //src/ui/lib/escher/test:force_waterfall_to_build_on_host
group("escher") {
  deps = [
    ":escher_rainfall_on_fb",
    ":escher_rainfall_on_scenic",
    ":escher_waterfall_on_fb",
    ":escher_waterfall_on_scenic",
  ]
}

renamed_binary("waterfall_bin_on_fb") {
  dest = "bin/escher_examples"
  source = "$root_out_dir/waterfall_on_fb"
  source_deps = [ "waterfall:waterfall_on_fb" ]
}

fuchsia_package_with_single_component("escher_waterfall_on_fb") {
  manifest = "meta/escher_examples_on_fb.cml"
  deps = [
    ":waterfall_bin_on_fb",
    "//src/lib/vulkan:vulkan_validation_layers",
    "//src/lib/vulkan/swapchain:image_pipe_swapchain_fb_layer",
    "//src/ui/examples/escher/common/assets:escher_examples_assets",
    "//src/ui/lib/escher/shaders:escher_shaders_resources",
  ]
}

renamed_binary("waterfall_bin_on_scenic") {
  dest = "bin/escher_examples"
  source = "$root_out_dir/waterfall_on_scenic"
  source_deps = [ "waterfall:waterfall_on_scenic" ]
}

fuchsia_package_with_single_component("escher_waterfall_on_scenic") {
  manifest = "meta/escher_examples_on_scenic.cml"
  deps = [
    ":waterfall_bin_on_scenic",
    "//src/lib/vulkan:vulkan_validation_layers",
    "//src/lib/vulkan/swapchain:image_pipe_swapchain_layer",
    "//src/ui/examples/escher/common/assets:escher_examples_assets",
    "//src/ui/lib/escher/shaders:escher_shaders_resources",
  ]
}

resource("flat_main.vert") {
  sources = [ "//src/ui/lib/escher/shaders/flatland/flat_main.vert" ]
  outputs = [ "data/shaders/flatland/flat_main.vert" ]
  visibility = [ ":*" ]
}

resource("flat_main.frag") {
  sources = [ "//src/ui/lib/escher/shaders/flatland/flat_main.frag" ]
  outputs = [ "data/shaders/flatland/flat_main.frag" ]
  visibility = [ ":*" ]
}

renamed_binary("rainfall_bin_on_fb") {
  dest = "bin/escher_examples"
  source = "$root_out_dir/rainfall_on_fb"
  source_deps = [ "rainfall:rainfall_on_fb" ]
}

fuchsia_package_with_single_component("escher_rainfall_on_fb") {
  manifest = "meta/escher_examples_on_fb.cml"
  deps = [
    ":flat_main.frag",
    ":flat_main.vert",
    ":rainfall_bin_on_fb",
    "//src/lib/vulkan:vulkan_validation_layers",
    "//src/lib/vulkan/swapchain:image_pipe_swapchain_fb_layer",
  ]
}

renamed_binary("rainfall_bin_on_scenic") {
  dest = "bin/escher_examples"
  source = "$root_out_dir/rainfall_on_scenic"
  source_deps = [ "rainfall:rainfall_on_scenic" ]
}

fuchsia_package_with_single_component("escher_rainfall_on_scenic") {
  manifest = "meta/escher_examples_on_scenic.cml"
  deps = [
    ":flat_main.frag",
    ":flat_main.vert",
    ":rainfall_bin_on_scenic",
    "//src/lib/vulkan:vulkan_validation_layers",
    "//src/lib/vulkan/swapchain:image_pipe_swapchain_layer",
  ]
}