src/ui/a11y/lib/magnifier/tests/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("tests") {
  testonly = true
  public_deps = [ ":magnifier_tests" ]
}

group("integration-tests") {
  testonly = true
  public_deps = [ ":magnification-pixeltest" ]
}

executable("magnifier_tests") {
  testonly = true

  sources = [
    "magnifier2_unittest.cc",
    "magnifier_util_test.cc",
  ]

  deps = [
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/ui/a11y/lib/gesture_manager/arena/tests/mocks",
    "//src/ui/a11y/lib/gesture_manager/tests/mocks",
    "//src/ui/a11y/lib/magnifier",
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/zx",
  ]

  # TODO(https://fxbug.dev/42136089): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

executable("magnification_pixeltest_bin") {
  testonly = true
  sources = [ "magnification_pixeltest.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.accessibility:fuchsia.accessibility_hlcpp",
    "//sdk/fidl/fuchsia.ui.composition:fuchsia.ui.composition_hlcpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/ui/a11y/testing/fidl:test.accessibility_hlcpp",
    "//src/ui/testing/ui_test_manager",
    "//src/ui/testing/util",
    "//third_party/googletest:gmock",
    "//third_party/googletest:gtest",
  ]
}

fuchsia_test_component("magnification-pixeltest-component") {
  component_name = "magnification-pixeltest-component"
  manifest = "meta/magnification_pixel_test.cml"
  deps = [ ":magnification_pixeltest_bin" ]
  test_type = "vulkan"
}

fuchsia_test_package("magnification-pixeltest") {
  test_components = [ ":magnification-pixeltest-component" ]
  test_specs = {
    log_settings = {
      # TODO(https://fxbug.dev/42174827): Investigate flakes and remove allowing ERROR severity.
      max_severity = "ERROR"
    }
    environments = [
      {
        dimensions = {
          # Ensure the device has Vulkan.
          device_type = "AEMU"
        }
      },
    ]
  }
}