src/sys/time/testing/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/fidl/fidl.gni")
import("//build/rust/rustc_library.gni")

group("testing") {
  testonly = true
  deps = [
    ":tests",
    ":timekeeper_integration",
    "example",
    "realm-proxy",
  ]
}

group("tests") {
  testonly = true
  deps = [
    "example:tests",
    "fidl",
  ]
}

rustc_library("timekeeper_integration") {
  testonly = true
  name = "timekeeper_integration_lib"
  edition = "2021"

  sources = [ "lib/lib.rs" ]

  source_root = "lib/lib.rs"

  deps = [
    "fidl/test.time:fidl_rust",
    "fidl/test.time.realm:fidl_rust",
    "//sdk/fidl/fuchsia.hardware.rtc:fuchsia.hardware.rtc_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/fidl/fuchsia.metrics:fuchsia.metrics_rust",
    "//sdk/fidl/fuchsia.metrics.test:fuchsia.metrics.test_rust",
    "//sdk/fidl/fuchsia.time:fuchsia.time_rust",
    "//sdk/fidl/fuchsia.time.external:fuchsia.time.external_rust",
    "//src/lib/async-utils",
    "//src/lib/fake-clock/fidl:fidl_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-component-test",
    "//src/lib/fuchsia-sync",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/storage/lib/vfs/rust:vfs",
    "//src/sys/time/lib/push-source",
    "//src/sys/time/lib/time_metrics_registry",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:chrono",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:lazy_static",
    "//third_party/rust_crates:tracing",
  ]
}

fuchsia_component_manifest("manifest_for_integration") {
  testonly = true
  component_name = "timekeeper_for_integration"
  manifest = "meta/timekeeper_for_integration.cml"
}

fuchsia_component_manifest("manifest_with_fake_time") {
  testonly = true
  component_name = "timekeeper_with_fake_time"
  manifest = "meta/timekeeper_with_fake_time.cml"
}

fuchsia_component("timekeeper_for_integration") {
  testonly = true
  cm_label = ":manifest_for_integration"
  deps = [ "//src/sys/time/timekeeper:bin" ]
}

fuchsia_component("timekeeper_with_fake_time") {
  testonly = true
  cm_label = ":manifest_with_fake_time"
  deps = [ "//src/sys/time/timekeeper:bin_with_fake_time" ]
}

fuchsia_structured_config_values("config-values-faketime") {
  testonly = true
  cm_label = ":timekeeper_with_fake_time"
  values_source = "config/values.json5"
}

fuchsia_structured_config_values("config-values-integration") {
  testonly = true
  cm_label = ":timekeeper_for_integration"
  values_source = "config/values.json5"
}