src/sys/component_manager/tests/routing/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

group("tests") {
  testonly = true

  deps = [ ":routing_integration_test" ]
}

rustc_test("routing_integration_test_bin") {
  name = "routing_integration_test"
  edition = "2021"
  source_root = "integration_test.rs"
  deps = [
    "//sdk/fidl/fuchsia.component:fuchsia.component_rust",
    "//sdk/fidl/fuchsia.component.decl:fuchsia.component.decl_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/sys/component_manager/tests/fidl:components_rust",
  ]

  sources = [ "integration_test.rs" ]
}

fuchsia_component("trigger") {
  testonly = true
  deps = [ "//src/sys/component_manager/tests:trigger_bin" ]
  manifest = "meta/trigger.cml"
}

fuchsia_unittest_package("routing_integration_test") {
  manifest = "meta/routing_integration_test.cml"
  deps = [
    ":routing_integration_test_bin",
    ":trigger",

    # https://fxbug.dev/42052321: Dep included for affected tests presubmit
    "//src/sys/component_manager:component-manager-realm-builder-cmp",
    "//src/sys/component_manager/testing/echo_server",
  ]
}