src/storage/lib/paver/test/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/fuzz.gni")
import("//build/test.gni")

test("test") {
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }

  output_name = "paver-test"
  sources = [
    "abr-test.cc",
    "data-sink-test.cc",
    "device-partitioner-test.cc",
    "fvm-test.cc",
    "main.cc",
    "partition-client-test.cc",
    "paver-context-test.cc",
    "paversvc-test.cc",
    "stream-reader-test.cc",
    "test-utils.cc",
    "validation-test.cc",
  ]
  deps = [
    "//sdk/fidl/fuchsia.boot:fuchsia.boot_cpp",
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",
    "//sdk/fidl/fuchsia.device.manager:fuchsia.device.manager_cpp",
    "//sdk/fidl/fuchsia.fshost:fuchsia.fshost_cpp",
    "//sdk/fidl/fuchsia.hardware.block:fuchsia.hardware.block_cpp",
    "//sdk/fidl/fuchsia.hardware.block.partition:fuchsia.hardware.block.partition_cpp",
    "//sdk/fidl/fuchsia.hardware.power.statecontrol:fuchsia.hardware.power.statecontrol_cpp_testing",
    "//sdk/fidl/fuchsia.hardware.skipblock:fuchsia.hardware.skipblock_cpp",
    "//sdk/fidl/fuchsia.kernel:fuchsia.kernel_cpp",
    "//sdk/fidl/fuchsia.paver:fuchsia.paver_cpp",
    "//sdk/fidl/fuchsia.scheduler:fuchsia.scheduler_cpp",
    "//sdk/fidl/fuchsia.tracing.provider:fuchsia.tracing.provider_cpp",
    "//sdk/lib/component/outgoing/cpp",
    "//sdk/lib/sys/cpp/testing:unit",
    "//src/devices/lib/amlogic",
    "//src/firmware/lib/abr",
    "//src/lib/uuid",
    "//src/storage/fvm",
    "//src/storage/gpt",
    "//src/storage/lib/block_client/cpp",
    "//src/storage/lib/fs_management",
    "//src/storage/lib/paver",
    "//src/storage/lib/ramdevice_client/cpp:ramdevice-client-test",
    "//src/storage/lib/utils:topological_path",
    "//src/storage/lib/vfs/cpp",
    "//third_party/android/platform/system:sparse_format",
    "//zircon/kernel/lib/arch",
    "//zircon/system/ulib/async",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fdio-caller",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/mock-boot-arguments",
    "//zircon/system/ulib/svc",
    "//zircon/system/ulib/sysconfig-client:sysconfig-sync-client",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
    "//zircon/third_party/ulib/cksum",
  ]
}

fuchsia_unittest_package("paver-test") {
  deps = [
    ":test",
    "//src/devices/block/drivers/core",
    "//src/devices/block/drivers/ftl",
    "//src/devices/block/drivers/gpt",
    "//src/devices/block/drivers/mbr",
    "//src/devices/block/drivers/ramdisk",
    "//src/devices/board/drivers/integration-test",
    "//src/devices/bus/drivers/platform",
    "//src/devices/nand/drivers/nand",
    "//src/devices/nand/drivers/nandpart",
    "//src/devices/nand/drivers/ram-nand",
    "//src/devices/nand/drivers/skip-block",
    "//src/storage/fvm/driver",
  ]
  test_specs = {
    # Gives more timeout to reduce flake.(https://fxbug.dev/42182211)
    timeout_secs = 720
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

fuchsia_library_fuzzer("paver-validation-fuzzer") {
  sources = [ "validation-fuzzer.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.boot:fuchsia.boot_cpp",
    "//sdk/fidl/fuchsia.device:fuchsia.device_cpp",
    "//sdk/fidl/fuchsia.fshost:fuchsia.fshost_cpp",
    "//sdk/fidl/fuchsia.hardware.block:fuchsia.hardware.block_cpp",
    "//sdk/fidl/fuchsia.hardware.skipblock:fuchsia.hardware.skipblock_cpp",
    "//sdk/fidl/fuchsia.paver:fuchsia.paver_cpp",
    "//src/storage/gpt",
    "//src/storage/lib/block_client/cpp",
    "//src/storage/lib/paver:paver-core",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fdio-caller",
    "//zircon/system/ulib/svc",
    "//zircon/system/ulib/sysconfig-client:sysconfig-sync-client",
    "//zircon/system/ulib/zx",
  ]

  include_dirs = [
    "//src/storage/lib/paver",
    "..",
  ]
}

fuchsia_fuzzer_component("paver-validation-fuzzer-component") {
  manifest = "meta/paver-validation-fuzzer.cml"
  deps = [ ":paver-validation-fuzzer" ]
}

fuchsia_fuzzer_package("paver-fuzzers") {
  cpp_fuzzer_components = [ ":paver-validation-fuzzer-component" ]
}