src/settings/service/integration_tests/factory_reset_tests/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/config.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_test.gni")

rustc_test("bin") {
  name = "factory_reset_integration_test"
  edition = "2021"
  source_root = "src/factory_reset_tests.rs"
  sources = [
    "src/common.rs",
    "src/factory_reset_tests.rs",
  ]
  deps = [
    "//sdk/fidl/fuchsia.recovery.policy:fuchsia.recovery.policy_rust",
    "//sdk/fidl/fuchsia.settings:fuchsia.settings_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-component-test",
    "//src/settings/service/integration_tests/utils",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:futures",
  ]

  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
}

fuchsia_component("factory_reset_integration_test") {
  testonly = true
  manifest = "meta/factory_reset_integration_test.cml"
  deps = [ ":bin" ]
}

fuchsia_test_package("factory_reset_integration_test_pkg") {
  package_name = "factory_reset_integration_test"
  test_components = [ ":factory_reset_integration_test" ]
  deps = [
    ":factory_reset_integration_test",
    ":tests_config",
    "//src/settings/service:setui_service_v2",
    "//src/sys/stash:pkg",
  ]
  subpackages = [ "//src/sys/stash:pkg" ]
}

resource("tests_config") {
  sources = [ "testdata/interface_configuration.json" ]
  outputs = [ "factory_reset_integration_test_pkg/{{source_file_part}}" ]
}

group("factory_reset_tests") {
  testonly = true
  public_deps = [ ":factory_reset_integration_test_pkg" ]
}