src/settings/inspect_utils/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")

group("inspect_utils") {
  testonly = true
  deps = [
    ":settings_inspect_utils",
    ":tests",
  ]
}

rustc_library("settings_inspect_utils") {
  name = "settings_inspect_utils"
  with_unit_tests = true
  edition = "2021"

  visibility = [
    ":*",
    "//src/settings/*",
  ]

  deps = [
    "//src/lib/diagnostics/inspect/derive",
    "//src/lib/diagnostics/inspect/rust",
  ]

  test_deps = [
    "//src/lib/diagnostics/testing/diagnostics-assertions/rust:diagnostics-assertions",
    "//src/lib/fuchsia",
  ]

  sources = [
    "src/joinable_inspect_vecdeque.rs",
    "src/lib.rs",
    "src/managed_inspect_map.rs",
    "src/managed_inspect_queue.rs",
  ]

  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
  configs += [ "//build/config/rust/lints:clippy_warn_all" ]
}

fuchsia_unittest_package("settings_inspect_utils_tests") {
  component_name = "settings_inspect_utils_test"
  manifest = "meta/settings_inspect_utils_tests.cml"
  deps = [ ":settings_inspect_utils_test" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [ ":settings_inspect_utils_tests" ]
}