src/media/codec/BUILD.gn

# Copyright 2016 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/config.gni")
import("//src/sys/core/build/core_shard.gni")

group("codec") {
  testonly = true
  deps = [
    ":codec_factory",
    ":codec_factory_test",
    ":services",
    ":tests",
    "//src/media/codec/codecs",
    "//src/media/codec/factory",
  ]
}

group("tests") {
  testonly = true
  deps = [
    "//src/media/codec/codecs:tests",
    "//src/media/codec/examples:encode-camera",
    "//src/media/codec/examples:encode-file",
    "//src/media/codec/examples:h264_decoder_fuzzer_tests",
    "//src/media/codec/examples:use_h264_decoder_frame_num_gaps_tests",
    "//src/media/codec/examples:use_h264_decoder_secure_input_output_test",
    "//src/media/codec/examples:use_h264_decoder_secure_output_tests",
    "//src/media/codec/examples:use_h264_decoder_stream_switching_tests",
    "//src/media/codec/examples:use_h264_decoder_tests",
    "//src/media/codec/examples:use_h264_sw_decoder_tests",
    "//src/media/codec/examples:use_media_decoder",
    "//src/media/codec/examples:use_vp9_decoder_24_output_frames_tests",
    "//src/media/codec/examples:use_vp9_decoder_secure_input_output_test",
    "//src/media/codec/examples:use_vp9_decoder_secure_output_tests",
    "//src/media/codec/examples:use_vp9_decoder_skip_first_frame_tests",
    "//src/media/codec/examples:use_vp9_decoder_stream_switching_tests",
    "//src/media/codec/examples:use_vp9_decoder_tests",
    "//src/media/codec/examples:vp9-decoder-conformance-test--bear-vp9",
    "//src/media/codec/examples:vp9_decoder_canary_conformance_tests",
    "//src/media/codec/examples:vp9_decoder_fuzzer_tests",
    "//src/media/codec/factory:codec_detect_hw_decode_test",
    "//src/media/codec/factory:codec_factory_integration_test",
  ]
}

core_shard("codec_factory_shard") {
  shard_file = "factory/meta/codec_factory.core_shard.cml"
}

group("hw_dependent_tests") {
  testonly = true
  deps = [ "//src/media/codec/codecs:hw_dependent_tests" ]
}

group("services") {
  public_deps = [ "//src/media/codec/factory" ]
}

fuchsia_package("codec_factory") {
  deps = [ ":factory_with_sw_codecs" ]
}

# Codec factory package dedicated for testing.
# It may contain codec components that are not yet fully released.
fuchsia_package("codec_factory_test") {
  testonly = true
  deps = [
    # TODO(https://fxbug.dev/42077655): move to `sw_codecs` when ready for prod
    # and make available based on product requirements.
    ":codec_runner_sw_cvsd_comp",
    ":codec_runner_sw_lc3_comp",
    ":sw_codecs",
    "//src/media/codec/factory:component",
  ]
}

group("factory_with_sw_codecs") {
  deps = [
    ":sw_codecs",
    "//src/media/codec/factory:component",
  ]
}

group("sw_codecs") {
  deps = [
    ":codec_runner_sw_aac_comp",
    ":codec_runner_sw_ffmpeg_comp",
    ":codec_runner_sw_sbc_comp",
  ]
}

fuchsia_component("codec_runner_sw_sbc_comp") {
  manifest = "codecs/meta/codec_runner_sw_sbc.cml"
  deps = [ "//src/media/codec/codecs/sw/sbc:codec_runner_sw_sbc" ]
  component_name = "codec_runner_sw_sbc"
}

fuchsia_component("codec_runner_sw_aac_comp") {
  manifest = "codecs/meta/codec_runner_sw_aac.cml"
  deps = [ "//src/media/codec/codecs/sw/aac:codec_runner_sw_aac" ]
  component_name = "codec_runner_sw_aac"
}

fuchsia_component("codec_runner_sw_ffmpeg_comp") {
  manifest = "codecs/meta/codec_runner_sw_ffmpeg.cml"
  deps = [ "//src/media/codec/codecs/sw/ffmpeg:codec_runner_sw_ffmpeg" ]
  component_name = "codec_runner_sw_ffmpeg"
}

fuchsia_component("codec_runner_sw_cvsd_comp") {
  manifest = "codecs/meta/codec_runner_sw_cvsd.cml"
  deps = [ "//src/media/codec/codecs/sw/cvsd:codec_runner_sw_cvsd" ]
  component_name = "codec_runner_sw_cvsd"
}

fuchsia_component("codec_runner_sw_lc3_comp") {
  manifest = "codecs/meta/codec_runner_sw_lc3.cml"
  deps = [ "//src/media/codec/codecs/sw/lc3:codec_runner_sw_lc3" ]
  component_name = "codec_runner_sw_lc3"
}