src/graphics/display/bin/display-test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/assembly/bootfs_files_for_assembly.gni")
import("//build/components.gni")

executable("display-test") {
  visibility = [ ":*" ]
  sources = [ "main.cc" ]
  deps = [
    "//sdk/banjo/fuchsia.hardware.display.controller:fuchsia.hardware.display.controller_banjo_cpp",
    "//sdk/fidl/fuchsia.hardware.display:fuchsia.hardware.display_cpp",
    "//sdk/fidl/fuchsia.hardware.display.types:fuchsia.hardware.display.types_cpp",
    "//sdk/fidl/fuchsia.sysinfo:fuchsia.sysinfo_cpp",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_cpp",
    "//sdk/lib/component/incoming/cpp",
    "//sdk/lib/fidl",
    "//src/graphics/display/testing/client-utils",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fzl",
    "//zircon/system/ulib/sysmem-version",
    "//zircon/system/ulib/zircon-internal",
    "//zircon/system/ulib/zx",
  ]
}

bootfs_files_for_assembly("bootfs") {
  deps = [ ":display-test" ]
}

fuchsia_test_component("display-test-cmp") {
  component_name = "display-test"
  deps = [ ":display-test" ]
  manifest = "meta/display-test.cml"
  test_type = "system"
}

fuchsia_test_package("display-test-test") {
  test_components = [ ":display-test-cmp" ]
  test_specs = {
    # manual test
    environments = []
  }
}

group("tests") {
  testonly = true
  deps = [ ":display-test-test" ]
}