src/devices/tests/v2/driver-runner-integration/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/rust/rustc_test.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [ ":package" ]
}

rustc_test("driver_runner_integration_test") {
  edition = "2021"
  testonly = true
  source_root = "driver_runner_integration_test.rs"
  sources = [ "driver_runner_integration_test.rs" ]
  deps = [
    "//sdk/fidl/fuchsia.driver.test:fuchsia.driver.test_rust",
    "//sdk/lib/driver_test_realm/realm_builder/rust",
    "//src/lib/diagnostics/reader/rust",
    "//src/lib/diagnostics/testing/diagnostics-assertions/rust:diagnostics-assertions",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component-test",
    "//src/sys/lib/component-events",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
  ]
}

fuchsia_component("component") {
  component_name = "driver_runner_integration_test"
  testonly = true
  manifest = "meta/driver_runner_integration_test.cml"
  deps = [ ":driver_runner_integration_test" ]
}

fuchsia_test_package("package") {
  package_name = "driver_runner_integration_test"
  test_components = [ ":component" ]

  # TODO(fxdebug.dev/80878): Make ERROR logs fail the test.
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  deps = [
    "//src/devices/bin/driver_host:component",
    "//src/devices/misc/drivers/packaged:component",
  ]
}