src/devices/sysmem/bin/sysmem_connector/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

executable("sysmem_connector_executable") {
  output_name = "sysmem_connector"

  sources = [
    "app.cc",
    "main.cc",
  ]

  deps = [
    "//sdk/fidl/fuchsia.metrics:fuchsia.metrics_hlcpp",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_hlcpp",
    "//sdk/fidl/fuchsia.sysmem2:fuchsia.sysmem2_hlcpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//sdk/lib/vfs/cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/sysmem-connector",
    "//zircon/system/ulib/trace-provider",
  ]
}

fuchsia_component("sysmem_connector_cmp") {
  component_name = "sysmem_connector"
  manifest = "meta/sysmem_connector.cml"
  deps = [ ":sysmem_connector_executable" ]
}

fuchsia_package("pkg") {
  package_name = "sysmem_connector"
  deps = [ ":sysmem_connector_cmp" ]
}

executable("sysmem_connector_test_executable") {
  testonly = true
  output_name = "sysmem_connector_test"

  sources = [ "test/sysmem_connector_test.cc" ]

  deps = [
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_hlcpp",
    "//sdk/fidl/fuchsia.sysmem2:fuchsia.sysmem2_hlcpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fsl",
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gtest",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

fuchsia_test_component("sysmem_connector_test_component") {
  manifest = "meta/sysmem_connector_test.cml"
  deps = [ ":sysmem_connector_test_executable" ]
  test_type = "system"
}

fuchsia_test_package("sysmem_connector_test") {
  test_components = [ ":sysmem_connector_test_component" ]
  deps = [ ":sysmem_connector_cmp" ]
}