src/devices/pci/testing/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/cpp/library_headers.gni")
import("//build/test.gni")

library_headers("pci-protocol-fake-headers") {
  include_dir = "."
  headers = [ "pci_protocol_fake.h" ]
}

source_set("pci-protocol-fake") {
  sources = [
    "protocol/fidl.cc",
    "protocol/internal.cc",
  ]
  public_deps = [
    ":pci-protocol-fake-headers",
    "//src/devices/pci/lib/device-protocol-pci",
    "//src/devices/testing/fake-bti",
    "//src/devices/testing/fake-resource",
    "//zircon/system/ulib/async:async-cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
  ]
  deps = [ "//sdk/lib/stdcompat" ]
  testonly = true
}

test("pci-protocol-fake-test") {
  sources = [ "pci_protocol_fake_tests.cc" ]
  deps = [
    "//src/devices/lib/mmio",
    "//src/devices/pci/lib/device-protocol-pci",
    "//src/devices/pci/testing:pci-protocol-fake",
    "//zircon/system/ulib/async:async-cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/zxtest",
  ]

  # TODO(https://fxbug.dev/42136089): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

fuchsia_unittest_package("pci-protocol-fake-test-package") {
  component_name = "pci-protocol-fake-test"
  deps = [ ":pci-protocol-fake-test" ]
}

group("tests") {
  testonly = true
  deps = [ ":pci-protocol-fake-test-package" ]
}