src/devices/block/bin/sdio/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/assembly/bootfs_files_for_assembly.gni")
import("//build/components.gni")
import("//build/test.gni")

executable("sdio") {
  visibility = [ ":*" ]
  sources = [
    "main.cc",
    "sdio.cc",
  ]
  deps = [
    "//sdk/fidl/fuchsia.hardware.sdio:fuchsia.hardware.sdio_cpp",
    "//sdk/lib/component/incoming/cpp",
  ]
}

bootfs_files_for_assembly("bootfs") {
  deps = [ ":sdio" ]
}

test("sdio-test-bin") {
  output_name = "sdio-test"
  sources = [
    "sdio-test.cc",
    "sdio.cc",
  ]
  include_dirs = [ "." ]
  deps = [
    "//sdk/fidl/fuchsia.hardware.sdio:fuchsia.hardware.sdio_cpp",
    "//src/devices/testing/driver-runtime-main:zxtest",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("sdio-test") {
  deps = [ ":sdio-test-bin" ]
  test_specs = {
    environments = basic_envs
  }
}

group("tests") {
  testonly = true
  deps = [ ":sdio-test" ]
}