src/devices/bin/driver_runtime/microbenchmarks/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/testing/perf/test.gni")

fidl("fuchsia.runtime.microbenchmarks") {
  sources = [ "test.fidl" ]
  public_deps = [ "//zircon/vdso/zx" ]
  contains_drivers = true
}

executable("bin") {
  output_name = "driver_runtime_microbenchmarks"
  testonly = true
  sources = [
    "arena.cc",
    "channels.cc",
    "dispatchers.cc",
    "handle.cc",
    "integration.cc",
    "message_packet.cc",
    "one_way.cc",
    "round_trips.cc",
    "test_runner.cc",
  ]
  deps = [
    ":fuchsia.runtime.microbenchmarks_cpp",
    "//sdk/lib/driver/runtime:driver_runtime_cpp",
    "//sdk/lib/driver/runtime:driver_runtime_env",
    "//sdk/lib/driver/runtime:driver_runtime_env_cpp",
    "//sdk/lib/driver/runtime:driver_runtime_testing",
    "//sdk/lib/driver/runtime/testing/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/devices/bin/driver_runtime:driver_runtime_impl",
    "//src/devices/lib/driver:driver_runtime",
    "//zircon/system/ulib/async:async-cpp",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/sync:sync-cpp",
    "//zircon/system/ulib/zx",
  ]
  public_deps = [ "//zircon/system/ulib/perftest" ]
}

fuchsia_unittest_package("driver_runtime_microbenchmarks") {
  manifest = "meta/driver_runtime_microbenchmarks.cml"

  deps = [ ":bin" ]
  test_type = "system"
}

fuchsia_component_perf_test("driver_runtime_microbenchmarks_test") {
  package = ":driver_runtime_microbenchmarks"
  component_name = "driver_runtime_microbenchmarks"
  test_component_args = [
    "-p",
    "--quiet",
  ]
  results_path_test_arg = "--out"

  expected_metric_names_filepath = "//src/tests/end_to_end/perf/expected_metric_names/fuchsia.driver_runtime_microbenchmarks.txt"
}

group("microbenchmarks") {
  testonly = true
  deps = [ ":driver_runtime_microbenchmarks_test" ]
}