src/connectivity/policy/netcfg/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/config.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_library.gni")
import("//src/connectivity/network/unified_binary/network_unified_binary.gni")

rustc_library("lib") {
  name = "netcfg"
  with_unit_tests = true
  edition = "2021"

  deps = [
    "//sdk/fidl/fuchsia.device:fuchsia.device_rust",
    "//sdk/fidl/fuchsia.hardware.network:fuchsia.hardware.network_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/fidl/fuchsia.net:fuchsia.net_rust",
    "//sdk/fidl/fuchsia.net.dhcp:fuchsia.net.dhcp_rust",
    "//sdk/fidl/fuchsia.net.dhcpv6:fuchsia.net.dhcpv6_rust",
    "//sdk/fidl/fuchsia.net.filter:fuchsia.net.filter_rust",
    "//sdk/fidl/fuchsia.net.filter.deprecated:fuchsia.net.filter.deprecated_rust",
    "//sdk/fidl/fuchsia.net.interfaces:fuchsia.net.interfaces_rust",
    "//sdk/fidl/fuchsia.net.interfaces.admin:fuchsia.net.interfaces.admin_rust",
    "//sdk/fidl/fuchsia.net.masquerade:fuchsia.net.masquerade_rust",
    "//sdk/fidl/fuchsia.net.name:fuchsia.net.name_rust",
    "//sdk/fidl/fuchsia.net.routes.admin:fuchsia.net.routes.admin_rust",
    "//sdk/fidl/fuchsia.net.stack:fuchsia.net.stack_rust",
    "//sdk/fidl/fuchsia.net.virtualization:fuchsia.net.virtualization_rust",
    "//sdk/fidl/fuchsia.process.lifecycle:fuchsia.process.lifecycle_rust",
    "//src/connectivity/lib/fidl_fuchsia_net_dhcpv6_ext",
    "//src/connectivity/lib/net-declare",
    "//src/connectivity/lib/net-types",
    "//src/connectivity/network/dhcpv4/lib",
    "//src/connectivity/network/lib/dns_server_watcher",
    "//src/connectivity/network/lib/netfilter",
    "//src/lib/async-utils",
    "//src/lib/diagnostics/log/rust",
    "//src/lib/fdio/rust:fdio",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-fs",
    "//src/lib/fuchsia-runtime",
    "//src/lib/network/fidl_fuchsia_net_dhcp_ext",
    "//src/lib/network/fidl_fuchsia_net_ext",
    "//src/lib/network/fidl_fuchsia_net_filter_ext",
    "//src/lib/network/fidl_fuchsia_net_interfaces_ext",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:argh",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:derivative",
    "//third_party/rust_crates:either",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:glob",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:serde_json",
    "//third_party/rust_crates:tracing",
  ]

  test_deps = [
    "//sdk/fidl/fuchsia.net.routes:fuchsia.net.routes_rust",
    "//src/lib/const-unwrap",
    "//src/lib/network/fidl_fuchsia_net_routes_ext",
    "//third_party/rust_crates:assert_matches",
    "//third_party/rust_crates:lazy_static",
    "//third_party/rust_crates:pretty_assertions",
    "//third_party/rust_crates:test-case",
  ]

  sources = [
    "src/devices.rs",
    "src/dhcpv4.rs",
    "src/dhcpv6.rs",
    "src/dns.rs",
    "src/errors.rs",
    "src/filter.rs",
    "src/interface.rs",
    "src/lib.rs",
    "src/masquerade.rs",
    "src/virtualization.rs",
  ]

  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
}

network_unified_binary("bin-basic") {
  edition = "2021"
  name = "netcfg_basic"
  source_root = "src/bin/basic.rs"

  deps = [
    ":lib",
    "//src/lib/fuchsia-async",
  ]

  sources = [ "src/bin/basic.rs" ]
}

rustc_binary("bin-advanced") {
  edition = "2021"
  name = "netcfg_advanced"
  source_root = "src/bin/advanced.rs"

  deps = [
    ":lib",
    "//src/lib/fuchsia-async",
  ]

  sources = [ "src/bin/advanced.rs" ]

  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
}

network_unified_binary_regular_and_gub_components("component-basic") {
  component_name = "netcfg-basic"
  manifest = "meta/netcfg-basic.cml"
  gub_deps = [ ":bin-basic" ]
}

network_unified_binary_regular_and_gub_packages("package-basic") {
  package_name = "netcfg-basic"
  gub_deps = [ ":component-basic" ]
  visibility = [ "//bundles/assembly/*" ]
}

fuchsia_component("component-advanced") {
  component_name = "netcfg-advanced"
  manifest = "meta/netcfg-advanced.cml"
  deps = [ ":bin-advanced" ]
}

fuchsia_package("package-advanced") {
  package_name = "netcfg-advanced"
  deps = [ ":component-advanced" ]
  visibility = [ "//bundles/assembly/*" ]
}

config_data("config-default") {
  for_pkg = "netcfg"
  sources = [ "config/netcfg_default.json" ]
  outputs = [ "netcfg_default.json" ]
}

fuchsia_unittest_package("netcfg-tests") {
  deps = [ ":lib_test" ]
  manifest = "meta/netcfg_lib_test.cml"
}

group("tests") {
  testonly = true
  deps = [ ":netcfg-tests" ]
}