src/connectivity/overnet/tests/integration/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/fidl/fidl.gni")
import("//build/rust/rustc_library.gni")

rustc_test("integration") {
  edition = "2021"
  output_name = "overnet_integration_tests"
  deps = [
    ":echo_rust",
    ":triangle_rust",
    "//src/connectivity/overnet/lib/circuit",
    "//src/connectivity/overnet/lib/core",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-sync",
    "//src/lib/zircon/rust:fuchsia-zircon-status",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  sources = [
    "src/drop.rs",
    "src/echo.rs",
    "src/lib.rs",
    "src/triangle.rs",
  ]

  if (is_host) {
    sources += [ "src/error_propagation.rs" ]
  }
}

fidl("echo") {
  testonly = true
  name = "test.echo"
  sources = [ "src/echo.test.fidl" ]
}

fidl("triangle") {
  testonly = true
  name = "test.triangle"
  sources = [ "src/triangle.test.fidl" ]
  public_deps = [ ":echo" ]
}

fuchsia_unittest_package("overnet-integration-tests") {
  deps = [ ":integration" ]
}

group("tests") {
  testonly = true
  deps = [
    ":integration($host_toolchain)",
    ":overnet-integration-tests",
  ]
}