src/connectivity/bluetooth/tests/bt-host-integration/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_test.gni")

rustc_test("bt_host_integration_tests") {
  edition = "2021"
  source_root = "src/lib.rs"
  deps = [
    "//sdk/fidl/fuchsia.bluetooth:fuchsia.bluetooth_rust",
    "//sdk/fidl/fuchsia.bluetooth.host:fuchsia.bluetooth.host_rust",
    "//sdk/fidl/fuchsia.bluetooth.sys:fuchsia.bluetooth.sys_rust",
    "//sdk/fidl/fuchsia.bluetooth.test:fuchsia.bluetooth.test_rust",
    "//src/connectivity/bluetooth/lib/fuchsia-bluetooth",
    "//src/connectivity/bluetooth/testing/bt-test-harness",
    "//src/connectivity/bluetooth/testing/hci-emulator-client",
    "//src/connectivity/bluetooth/testing/test-harness",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
  ]

  sources = [ "src/lib.rs" ]

  configs -= [ "//build/config/rust/lints:allow_unused_results" ]
}

fuchsia_test_component("bt-host-integration-tests-component") {
  manifest = "meta/bt-host-integration-tests.cml"
  deps = [ ":bt_host_integration_tests" ]
}

# Note: The integration tests includes the bt-hci-emulator driver
# component in this package via the dep on the bt-test-harness crate.
fuchsia_test_package("bt-host-integration-tests") {
  test_components = [ ":bt-host-integration-tests-component" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  subpackages = [ "//src/connectivity/bluetooth/core/bt-host" ]
}