src/connectivity/bluetooth/core/bt-host/socket/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bazel/bazel_fuchsia_test_package.gni")
import("//src/connectivity/bluetooth/core/bt-host/build/bt_gtest_package.gni")

source_set("socket") {
  sources = [
    "socket_channel_relay.h",
    "socket_factory.h",
  ]

  deps = [
    "//src/connectivity/bluetooth/core/bt-host/common",
    "//zircon/system/ulib/trace",
  ]

  public_deps = [
    "//sdk/lib/fit",
    "//zircon/system/ulib/async-default",
    "//zircon/system/ulib/zx",
  ]
}

source_set("tests") {
  testonly = true

  sources = [
    "socket_channel_relay_test.cc",
    "socket_factory_l2cap_integration_test.cc",
    "socket_factory_test.cc",
  ]

  deps = [
    ":socket",
    "//src/connectivity/bluetooth/core/bt-host/gap",
    "//src/connectivity/bluetooth/core/bt-host/l2cap:channel_manager_mock_controller_test_fixture",
    "//src/connectivity/bluetooth/core/bt-host/l2cap:testing",
    "//src/connectivity/bluetooth/core/bt-host/testing",
    "//src/connectivity/bluetooth/core/bt-host/testing:loop_fixture",
    "//src/connectivity/bluetooth/core/bt-host/transport:testing",
    "//third_party/pigweed/backends/pw_async_fuchsia:dispatcher",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
  ]

  # TODO(https://fxbug.dev/42085293): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-vla-cxx-extension" ]
}

bt_gtest_package("bt-host-socket-tests") {
  deps = [ ":tests" ]
}

bazel_fuchsia_test_package("test_pkg") {
  test_package_name = "socket_tests"
  test_component_names = [ "socket_test_autogen_cml" ]
}