src/cobalt/bin/testing/mock_cobalt/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

rustc_binary("bin") {
  name = "mock_cobalt"
  edition = "2021"
  with_unit_tests = true

  deps = [
    "//sdk/fidl/fuchsia.metrics:fuchsia.metrics_rust",
    "//sdk/fidl/fuchsia.metrics.test:fuchsia.metrics.test_rust",
    "//src/lib/cobalt/rust/builders",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  test_deps = [
    "//src/lib/async-utils",
    "//src/lib/fuchsia-async",
  ]

  sources = [ "src/main.rs" ]
}

fuchsia_component("component_v2") {
  component_name = "mock_cobalt"
  testonly = true
  manifest = "meta/mock_cobalt.cml"
  deps = [ ":bin" ]
}

fuchsia_package("mock_cobalt") {
  testonly = true
  deps = [ ":component_v2" ]
}

fuchsia_unittest_package("mock-cobalt-tests") {
  deps = [ ":bin_test" ]
}

group("tests") {
  testonly = true
  deps = [ ":mock-cobalt-tests" ]
}