src/camera/lib/stream_utils/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("stream_utils") {
  public_deps = [ ":lib" ]
}

group("tests") {
  testonly = true
  deps = [ ":image_io_util_unittest" ]
}

source_set("lib") {
  sources = [ "image_io_util.cc" ]
  deps = [
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_hlcpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/files",
    "//zircon/system/ulib/fzl",
  ]
  public_deps = [ "//sdk/lib/fit-promise" ]
}

source_set("stream_configs") {
  sources = [
    "stream_constraints.cc",
    "stream_constraints.h",
  ]
  deps = [
    "//sdk/fidl/fuchsia.camera2:fuchsia.camera2_hlcpp",
    "//sdk/fidl/fuchsia.camera2.hal:fuchsia.camera2.hal_hlcpp",
    "//src/camera/lib/format_conversion",
    "//zircon/system/ulib/affine",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/image-format",
  ]
}

executable("image_io_util_unittest_bin") {
  testonly = true
  sources = [ "image_io_util_unittest.cc" ]
  deps = [
    ":lib",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_hlcpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/files",
    "//src/lib/fxl/test:gtest_main",
  ]
}

fuchsia_unittest_package("image_io_util_unittest") {
  manifest = "meta/image_io_util_unittest.cml"
  deps = [ ":image_io_util_unittest_bin" ]
}