src/camera/drivers/test_utils/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("test_utils") {
  public_deps = [
    ":ddk_mock_operators",
    ":fake_buffer_collection",
  ]
  public_configs = [ ":test_utils_config" ]
}

group("tests") {
  testonly = true
  deps = [ ":fake_buffer_collection_unittest" ]
}

config("test_utils_config") {
  visibility = [ ":*" ]
  include_dirs = [ "." ]
}

source_set("fake_buffer_collection") {
  visibility = [ ":*" ]
  sources = [
    "fake_buffer_collection.cc",
    "fake_buffer_collection.h",
  ]
  deps = [ "//zircon/system/ulib/fbl" ]
  public_deps = [
    "//src/devices/lib/sysmem",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/system/ulib/image-format",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zircon-internal",
    "//zircon/third_party/ulib/safemath",
  ]
}

source_set("ddk_mock_operators") {
  visibility = [ ":*" ]
  sources = [ "ddk_mock_operators.h" ]
  public_deps = [ "//sdk/banjo/fuchsia.hardware.camera.sensor:fuchsia.hardware.camera.sensor_banjo_cpp" ]
}

executable("fake_buffer_collection_unittest_bin") {
  testonly = true
  sources = [ "fake_buffer_collection_unittest.cc" ]
  deps = [
    ":fake_buffer_collection",
    "//sdk/fidl/fuchsia.sysmem:fuchsia.sysmem_cpp",
    "//sdk/lib/fdio",
    "//sdk/lib/fit",
    "//src/devices/lib/mmio",
    "//src/devices/testing/fake-bti",
    "//src/lib/ddk",
    "//src/lib/fxl/test:gtest_main",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/hwreg",
    "//zircon/system/ulib/zx",
  ]
}

fuchsia_unittest_package("fake_buffer_collection_unittest") {
  deps = [ ":fake_buffer_collection_unittest_bin" ]
}