scripts/debug/zxdb_cli/cli/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/python/host.gni")
import("//build/python/python_host_test.gni")
import("//build/python/python_library.gni")

group("tests") {
  testonly = true
  deps = [ ":cli_test($host_toolchain)" ]
}

if (is_host) {
  python_library("cli_lib") {
    library_name = "cli"
    sources = [
      "__init__.py",
      "cli.py",
      "commands/__init__.py",
      "commands/attach.py",
      "commands/base.py",
      "commands/break_cmd.py",
      "commands/continue_cmd.py",
      "commands/detach.py",
      "commands/evaluate.py",
      "commands/get_state.py",
      "commands/pause.py",
      "commands/schema.py",
      "commands/stack_trace.py",
      "commands/start.py",
      "commands/stop.py",
      "commands/threads.py",
      "commands/variables.py",
      "commands/wait_for_event.py",
    ]
    deps = [
      "//scripts/debug/zxdb_cli/daemon_manager",
      "//scripts/debug/zxdb_cli/shared:protocol_lib",
      "//scripts/lib/fx_cmd",
    ]
  }

  python_host_test("cli_test") {
    main_source = "tests/test_cli.py"
    libraries = [ ":cli_lib" ]
    test_data_deps = [ "//prebuilt/third_party/pydantic-core:test_data" ]
  }
}