src/power/testing/thermal-test-control/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

fuchsia_package_with_single_component("thermal-test-control") {
  manifest = "meta/thermal_test_control.cmx"
  deps = [ ":thermal_test_control_bin" ]
}

fuchsia_component("thermal-test-control-v2") {
  testonly = true
  component_name = "thermal_test_control"
  manifest = "meta/thermal_test_control.cml"
  deps = [ ":thermal_test_control_bin" ]
}

executable("thermal_test_control_bin") {
  output_name = "thermal_test_control"
  sources = [
    "main.cc",
    "thermal_test_control.cc",
  ]
  deps = [
    "//sdk/fidl/fuchsia.thermal",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/power/fidl/testing:test.thermal",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
  ]
}

executable("thermal-test-control-test-bin") {
  testonly = true
  output_name = "thermal_test_control_test_bin"
  sources = [
    "thermal_test_control.cc",
    "thermal_test_control_unittest.cc",
  ]
  deps = [
    "//sdk/fidl/fuchsia.thermal",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:cpp",
    "//sdk/lib/syslog/cpp",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/power/fidl/testing:test.thermal",
    "//third_party/googletest:gtest",
  ]
}

fuchsia_unittest_package("thermal-test-control-test") {
  deps = [ ":thermal-test-control-test-bin" ]
}

group("tests") {
  testonly = true
  deps = [ ":thermal-test-control-test" ]
}