src/connectivity/network/tests/integration/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config.gni")
import("//src/sys/build/components.gni")

group("tests") {
  testonly = true
  deps = [
    ":netstack-integration-tests",
    "ip_forward:netemul-ip-forward-tests",
  ]
}

tests = [
  "cobalt",
  "dhcp",
  "dns",
  "fidl",
  "filter",
  "inspect",
  "ipv4",
  "ipv6",
  "management",
  "neighbor",
  "reachability",
  "routes",
  "socket",
  "sys",
]

foreach(test, tests) {
  name = "netstack_${test}_integration_test"
  fuchsia_test_component(name) {
    manifest = "meta/${name}.cmx"
    deps = [ test ]
  }
}

fuchsia_test_package("netstack-integration-tests") {
  package_name = "netstack-integration-tests"

  test_components = []
  foreach(test, tests) {
    test_components += [ ":netstack_${test}_integration_test" ]
  }
  deps = [
    # device_name_provider provides fuchsia.device.NameProvider.
    "..:device_name_provider",

    # mock_cobalt provides fuchsia.cobalt.LoggerFactory and fuchsia.cobalt.test.LoggerQuerier.
    "//src/cobalt/bin/testing/mock_cobalt:component_v1",

    # stash_secure is used by dhcpd and netstack.
    "//src/sys/stash:stash_secure",

    # dhcpd is used to test DHCP address acquisition.
    "//src/connectivity/network/dhcp:component-v1",

    # DHCPv6 client is under test.
    "//src/connectivity/network/dhcpv6/client:component",

    # dns_resolver integration with netstack is tested.
    "//src/connectivity/network/dns:component",

    # netcfg integration with netstack is tested.
    ":netcfg-netemul-config",
    "//src/connectivity/network/netcfg:component-netemul",

    # netstack3 is under test.
    "//src/connectivity/network/netstack3:component",

    # netstack is under test.
    "//src/connectivity/network/netstack:component-debug",

    # network_manager integration with netstack is tested.
    ":network-manager-config",
    "//src/connectivity/management/network-manager:component-netemul",

    # reachability monitor is tested.
    "//src/connectivity/management/reachability:component",

    # netemul-sandbox is used to create hermetic environments.
    "//src/connectivity/network/testing/netemul/runner:netemul-sandbox-component",
  ]
}

config_data("netcfg-netemul-config") {
  testonly = true
  for_pkg = "netstack-integration-tests"
  sources = [ "//src/connectivity/network/netcfg/config/empty.json" ]
  outputs = [ "netcfg/empty.json" ]
}

config_data("network-manager-config") {
  testonly = true
  for_pkg = "netstack-integration-tests"
  sources =
      [ "//src/connectivity/management/network-manager/config/default.json" ]
  outputs = [ "factory_config.json" ]
}