src/developer/forensics/feedback_data/annotations/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

visibility = [ "//src/developer/forensics/feedback_data/*" ]

###############################################################################
# SOURCES
###############################################################################
source_set("annotation_providers") {
  public = [
    "annotation_provider.h",
    "annotation_provider_factory.h",
  ]

  sources = [
    "annotation_provider.h",
    "annotation_provider_factory.cc",
    "annotation_provider_factory.h",
    "device_id_provider.cc",
    "device_id_provider.h",
  ]

  deps = [
    ":channel_provider",
    ":timezone_provider",
    ":types",
    ":utils",
    "//sdk/lib/fit-promise",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//src/developer/forensics/feedback:device_id_provider",
    "//src/developer/forensics/feedback_data:constants",
    "//src/developer/forensics/utils:errors",
    "//src/developer/forensics/utils:time",
    "//src/lib/fxl",
    "//src/lib/timekeeper",
    "//src/lib/timekeeper:system",
  ]
}

# Exposed separately for unit test purposes.
source_set("channel_provider") {
  public = [ "channel_provider.h" ]

  sources = [
    "annotation_provider.h",
    "channel_provider.cc",
    "channel_provider.h",
  ]

  public_deps = [
    ":types",
    "//sdk/fidl/fuchsia.update.channel",
    "//sdk/lib/sys/cpp",
    "//src/lib/fxl",
    "//zircon/system/ulib/async",
    "//zircon/system/ulib/zx",
  ]

  deps = [
    ":utils",
    "//src/developer/forensics/feedback_data:constants",
    "//src/developer/forensics/utils:errors",
    "//src/developer/forensics/utils/fidl:channel_provider_ptr",
    "//src/developer/forensics/utils/fit",
  ]
}

source_set("static_annotations") {
  public = [ "static_annotations.h" ]

  sources = [
    "static_annotations.cc",
    "static_annotations.h",
  ]

  public_deps = [
    ":types",
    "//src/developer/forensics/utils:previous_boot_file",
  ]

  deps = [
    ":utils",
    "//sdk/fidl/fuchsia.sysinfo",
    "//sdk/lib/fdio",
    "//sdk/lib/syslog/cpp",
    "//src/developer/forensics/feedback_data:constants",
    "//src/developer/forensics/utils:errors",
    "//src/lib/files",
    "//src/lib/fxl",
  ]
}

# Exposed separately for unit test purposes.
source_set("timezone_provider") {
  public = [ "timezone_provider.h" ]

  sources = [
    "annotation_provider.h",
    "timezone_provider.cc",
    "timezone_provider.h",
  ]

  public_deps = [
    ":types",
    "//sdk/fidl/fuchsia.intl",
    "//src/developer/forensics/utils:errors",
    "//src/developer/forensics/utils/fit",
  ]

  deps = [
    ":utils",
    "//sdk/lib/fit-promise",
    "//sdk/lib/sys/cpp",
    "//src/developer/forensics/feedback_data:constants",
    "//src/developer/forensics/utils:errors",
  ]
}

source_set("types") {
  sources = [ "types.h" ]

  public_deps = [
    "//sdk/lib/syslog/cpp",
    "//src/developer/forensics/utils:errors",
  ]

  visibility += [ "//src/developer/forensics/testing:gpretty_printers" ]
}

source_set("utils") {
  sources = [
    "utils.cc",
    "utils.h",
  ]

  public_deps = [
    ":types",
    "//sdk/fidl/fuchsia.feedback",
  ]

  deps = [ "//third_party/rapidjson" ]
}