src/sys/pkg/lib/fuchsia-merkle/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_library.gni")
import("//build/test/test_package.gni")
import("//build/testing/environments.gni")

rustc_library("fuchsia-merkle") {
  name = "fuchsia_merkle"
  edition = "2018"
  with_unit_tests = true

  deps = [
    "//src/lib/mundane",
    "//src/sys/pkg/lib/fuchsia-hash",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:hex",
    "//third_party/rust_crates:proptest",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:thiserror",
  ]

  # TODO(46721): Fix the leaks and remove this.
  non_rust_deps = [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]

  sources = [
    "src/builder.rs",
    "src/lib.rs",
    "src/tree.rs",
    "src/util.rs",
    "src/writer.rs",
  ]
}

unittest_package("fuchsia-merkle-tests") {
  deps = [ ":fuchsia-merkle_test" ]

  tests = [
    {
      name = "fuchsia_merkle_lib_test"
      environments = basic_envs
    },
  ]
}

group("tests") {
  testonly = true
  public_deps = [ ":fuchsia-merkle-tests" ]
}