garnet/bin/trace_manager/tests/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//src/sys/build/components.gni")

group("tests") {
  testonly = true
  deps = [ ":trace_manager_tests" ]
}

executable("trace_manager_tests_bin") {
  testonly = true

  output_name = "trace_manager_tests"

  sources = [
    "fake_provider.cc",
    "fake_provider.h",
    "init_to_fini_tests.cc",
    "initialize_tests.cc",
    "provider_tests.cc",
    "start_tests.cc",
    "stop_tests.cc",
    "terminate_tests.cc",
    "trace_manager_test.cc",
    "trace_manager_test.h",
  ]

  deps = [
    "//garnet/bin/trace_manager:lib",
    "//garnet/public/lib/gtest",
    "//sdk/lib/fdio",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/sys/cpp/testing:unit",
    "//src/lib/fxl/test:gtest_main",
    "//zircon/system/ulib/async-default",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/trace-provider",
  ]

  # TODO(fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

resource("tracing.config") {
  sources = [ "tracing.config" ]
  outputs = [ "data/{{source_file_part}}" ]
}

fuchsia_test_component("trace_manager_tests_component") {
  component_name = "trace_manager_tests"
  manifest = "meta/trace_manager_tests.cmx"
  deps = [ ":trace_manager_tests_bin" ]
}

fuchsia_test_package("trace_manager_tests") {
  test_components = [ ":trace_manager_tests_component" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
  deps = [ ":tracing.config" ]
}