src/graphics/lib/magma/tests/integration/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//src/graphics/lib/magma/gnbuild/magma.gni")

group("integration") {
  testonly = true

  public_deps = [ ":magma_abi_conformance_tests" ]
}

executable("magma_abi_conformance_tests") {
  testonly = true

  sources = [
    "main.cc",
    "test_magma_abi.cc",
    "test_magma_abi_c.c",
  ]

  deps = [
    "$magma_build_root/include:magma_abi",
    "$magma_build_root/src/libmagma",
    "$magma_build_root/tests/helper:magma_map_cpu",
    "//src/lib/fxl",
    "//third_party/googletest:gtest",
  ]

  if (is_fuchsia) {
    deps += [
      "//sdk/fidl/fuchsia.gpu.magma:fuchsia.gpu.magma_llcpp",
      "//sdk/fidl/fuchsia.sysmem",
      "//sdk/lib/fdio",
      "//src/graphics/lib/magma/src/magma_util/platform:logger",
      "//src/graphics/lib/magma/src/magma_util/platform:trace_provider",
      "//zircon/public/lib/fidl-llcpp",
      "//zircon/system/ulib/async-loop:async-loop-cpp",
    ]
  }

  # TODO(fxbug.dev/69585): This target uses raw zx::channel with LLCPP which is deprecated.
  # Please migrate to typed channel APIs (fidl::ClientEnd<T>, fidl::ServerEnd<T>).
  # See linked bug for details.
  configs += [ "//build/cpp:fidl-llcpp-deprecated-raw-channels" ]
}

executable("virtmagma_abi_conformance_tests") {
  testonly = true

  defines = [ "VIRTMAGMA=1" ]

  sources = [
    "main.cc",
    "test_magma_abi.cc",
    "test_magma_abi_c.c",
  ]

  deps = [
    "$magma_build_root/include:magma_abi",
    "$magma_build_root/src/libmagma_linux",
    "$magma_build_root/tests/helper:magma_map_cpu",
    "//src/lib/fxl",
    "//third_party/googletest:gtest",
  ]

  # TODO(fxbug.dev/69585): This target uses raw zx::channel with LLCPP which is deprecated.
  # Please migrate to typed channel APIs (fidl::ClientEnd<T>, fidl::ServerEnd<T>).
  # See linked bug for details.
  configs += [ "//build/cpp:fidl-llcpp-deprecated-raw-channels" ]
}