garnet/lib/magma/gnbuild/magma-vsl-gc/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config.gni")
import("//build/package.gni")
import("//garnet/lib/magma/gnbuild/magma.gni")

group("magma-vulkan") {
  if (magma_enable_developer_build) {
    testonly = true
  }
  public_deps = [
    ":magma-vsl-gc",
  ]
  if (build_libvulkan_vsl_gc != []) {
    public_deps += [ ":magma-vsl-gc-config" ]
  }
}

package("magma-vsl-gc") {
  deprecated_system_image = true
  if (magma_enable_developer_build) {
    testonly = true
  }

  deps = []

  if (magma_enable_developer_build) {
    deps += [ "//garnet/drivers/gpu/msd-vsl-gc:msd_vsl_test" ]
    drivers = [
      {
        name = "libmsd_vsl_test.so"
      },
    ]
  } else {
    deps += [ "//garnet/drivers/gpu/msd-vsl-gc:msd_vsl" ]
    drivers = [
      {
        name = "libmsd_vsl.so"
      },
    ]
  }

  resources = []
  libraries = []

  if (build_libvulkan_vsl_gc != []) {
    foreach(entry, build_libvulkan_vsl_gc) {
      icd_name = get_label_info(entry, "name")
      deps += [ entry ]

      libraries += [
        {
          name = "$icd_name.so"
        },
      ]
    }
  }
}

if (build_libvulkan_vsl_gc != []) {
  config_data("magma-vsl-gc-config") {
    sources = []
    foreach(entry, build_libvulkan_vsl_gc) {
      icd_name = get_label_info(entry, "name")
      filename = "$target_gen_dir/vulkan/icd.d/$icd_name.json"
      icd_data = [
        "{",
        "\"file_format_version\": \"1.0.0\",",
        "\"ICD\": {",
        "\"library_path\": \"$icd_name.so\",",
        "\"api_version\": \"1.0.68\"",
        "}",
        "}",
      ]
      write_file(filename, icd_data)
      sources += [ rebase_path(file_name) ]
    }
    for_pkg = "vulkan-icd"
    outputs = [
      "icd.d/{{source_file_part}}",
    ]
  }
}

package("nonhardware-tests") {
  testonly = true
  package_name = "magma_vsl_gc_nonhardware_tests"

  deps = [
    "//garnet/drivers/gpu/msd-vsl-gc:tests",
  ]

  tests = [
    {
      name = "msd_vsl_gc_nonhardware_tests"
    },
  ]
}