garnet/bin/sysmem-assistant/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config.gni")
import("//build/package.gni")

executable("bin") {
  output_name = "sysmem-assistant"

  sources = [
    "main.cc",
  ]

  deps = [
    "//sdk/lib/fidl/cpp",
    "//src/lib/fxl",
    "//zircon/public/fidl/fuchsia-hardware-tee",
    "//zircon/public/fidl/fuchsia-sysmem:fuchsia-sysmem_c",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fdio",
    "//zircon/public/lib/tee-client-api",
  ]
}

package("sysmem-assistant") {
  deps = [
    ":bin",
  ]

  binary = "sysmem-assistant"

  meta = [
    {
      path = rebase_path("meta/sysmem-assistant.cmx")
      dest = "sysmem-assistant.cmx"
    },
  ]
}

declare_args() {
  # The secmem TA must be obtained elsewhere and put into the firmware
  # directory.
  have_secmem_ta = false
}

package("ta-image") {
  deprecated_system_image = true

  secmem_ta_uuid = "2c1a33c0-44cc-11e5-bc3b-0002a5d5c51b"
  libraries = [
    {
      source = rebase_path("firmware/$secmem_ta_uuid.ta")
      name = "firmware/$secmem_ta_uuid.ta"
    },
  ]
}

config_data("config") {
  for_pkg = "sysmgr"
  sources = [
    "sysmem-assistant.config",
  ]
}

# Don't launch without a TA to use.
group("secmem-ta") {
  if (have_secmem_ta) {
    data_deps = [":ta-image", ":config"]
  }
}